      SUBROUTINE ZDSCAL( N, DA, ZX, INCX )
*
*     scales a vector by a constant.
*     jack dongarra, 3/11/78.
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
      DOUBLE PRECISION   DA
*     ..
*     .. Array Arguments ..
      COMPLEX*16         ZX( 1 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IX, NINCX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          DCMPLX
*     ..
*     .. Executable Statements ..
*
      IF( N.LE.0 )
     $   RETURN
      IF( INCX.EQ.1 )
     $   GO TO 20
*
*        code for increment not equal to 1
*
      IX = 1
      IF( INCX.LT.0 )
     $   IX = 1 - ( N-1 )*INCX
      NINCX = IX + ( N-1 )*INCX
      DO 10 I = IX, NINCX, INCX
         ZX( I ) = DCMPLX( DA, 0.0D0 )*ZX( I )
   10 CONTINUE
      RETURN
*
*        code for increment equal to 1
*
   20 DO 30 I = 1, N
         ZX( I ) = DCMPLX( DA, 0.0D0 )*ZX( I )
   30 CONTINUE
      RETURN
      END
